Estruturas de Seleção

**Simples**

Avalia uma condição e executa um ou mais comandos se a mesma for verdadeira. Após a execução dos comandos, o fluxo do programa segue normalmente. Se a condição for falsa, nenhum comando associado à mesma será executado.

**Sintaxe**

SE <CONDIÇÃO> ENTÃO (condição verdadeira)

*<COMANDO(S)>*

FIMSE

O bloco <COMANDO(S)> é executado somente a condição for VERDADEIRA

algoritmo "estrutura de seleção simples"

var

n: inteiro

inicio

escreva("Digite um número inteiro ")

leia(n)

se n MOD 2 = 0 entao

escreval("PAR")

fimse

fimalgoritmo

**Composta**

Avalia uma condição e executa um ou mais comandos se a mesma for verdadeira, ou executada um ou mais comandos se a mesma for falsa. Após a execução dos comandos, o fluxo do programa segue normalmente.

**Sintaxe**

SE <CONDIÇÃO> ENTÃO (condição verdadeira)

*<COMANDO(S)>*

SENÃO (condição falsa)

*<COMANDO(S)>*

FIMSE

O bloco <COMANDO(S)> associado ao ENTÃO é executado somente quando a condição for VERDADEIRA, e o bloco <COMANDO(S)> associado ao SENÃO é executado somente quando a condição for FALSA

algoritmo "estrutura de seleção composta"

var

n: inteiro

inicio

escreva("Digite um número inteiro ")

leia(n)

se n MOD 2 = 0 entao

escreval("PAR")

senao

escreva("ÍMPAR")

fimse

fimalgoritmo

**Encadeada ou aninhada**

Contempla a associação de uma ou mais estruturas de seleção, simples e/ou compostas.

algoritmo "estrutura de seleção encadeada"

var

n: inteiro

inicio

escreva("Digite um número inteiro ")

leia(n)

se n = 0 entao

escreval("ZERO")

senao

se n % 2 = 0 entao

escreva("PAR")

senao

escreva("ÍMPAR")

fimse

fimse

fimalgoritmo

**Seleção Múltipla:**

escolha <expressão-de-seleção>

caso <exp11>, <exp12>, ..., <exp1n>

*<seqüência-de-comandos-1>*

caso <exp21>, <exp22>, ..., <exp2n>

*<seqüência-de-comandos-2>*

...

outrocaso

*<seqüência-de-comandos-extra>*

fimescolha

algoritmo "operacoes"

var

op: inteiro

a, b : real

inicio

escreval("Escolha uma das operações: ")

escreval("1 - Adição")

escreval("2 - Subtração")

escreval("3 - Multiplicação")

escreval("4 – Divisão")

leia(op)

escreva("Informe o primeiro número: ")

leia(a)

escreva("Informe o segundo número: ")

leia(b)

escolha op

caso 1

escreval(a, " + ", b, " = ", a + b)

caso 2

escreval(a, " - ", b, " = ", a - b)

caso 3

escreval(a, " \* ", b, " = ", a \* b)

caso 4

se (b = 0) então

escreval("Erro de divisão por zero")

senao

escreval(a, " / ", b, " = ", a / b)

fimse

outrocaso

escreval("Opção inválida")

fimescolha

fimalgoritmo

**o mesmo problema resolvido com estrutura de seleção encadeada**

algoritmo "operacoes"

var

op: inteiro

a, b : real

inicio

escreval("Escolha uma das operações: ")

escreval("1 - Adição")

escreval("2 - Subtração")

escreval("3 - Multiplicação")

escreval("4 – Divisão")

leia(op)

escreva("Informe o primeiro número: ")

leia(a)

escreva("Informe o segundo número: ")

leia(b)

se op = 1 entao

escreval(a, " + ", b, " = ", a + b)

senao

se op = 2 entao

escreval(a, " - ", b, " = ", a - b)

senao

se op = 3 entao

escreval(a, " \* ", b, " = ", a \* b)

senao

se (op = 4) e (b = 0) entao

escreva("Erro de divisão por zero")

senao

se (op = 4) e (b <> 0) entao

escreval(a, " / ", b, " = ", a / b)

senao

escreval("Opção inválida")

fimse

fimse

fimse

fimse

fimse

fimalgoritmo